f83843ceba
* Add kotlin language Queries taken from https://github.com/nvim-treesitter/nvim-treesitter/blob/master/queries/kotlin seem to work well enough for my needs though I don't use kotlin heavily. * Update lang-support doc * Updates the kotlin highlight query to use helixs scopes * Updates the queries from PR feedback * Adds 'shallow = true' to gitmodules * Removes kotlin locals.scm * Remove blank line Co-authored-by: Ivan Tham <pickfire@riseup.net> Co-authored-by: Ivan Tham <pickfire@riseup.net>
36 lines
1 KiB
Scheme
36 lines
1 KiB
Scheme
((comment) @injection.content
|
|
(#set! injection.language "comment"))
|
|
|
|
; There are 3 ways to define a regex
|
|
; - "[abc]?".toRegex()
|
|
((call_expression
|
|
(navigation_expression
|
|
([(line_string_literal) (multi_line_string_literal)] @injection.content)
|
|
(navigation_suffix
|
|
((simple_identifier) @_function
|
|
(#eq? @_function "toRegex")))))
|
|
(#set! injection.language "regex"))
|
|
|
|
; - Regex("[abc]?")
|
|
((call_expression
|
|
((simple_identifier) @_function
|
|
(#eq? @_function "Regex"))
|
|
(call_suffix
|
|
(value_arguments
|
|
(value_argument
|
|
[ (line_string_literal) (multi_line_string_literal) ] @injection.content))))
|
|
(#set! injection.language "regex"))
|
|
|
|
; - Regex.fromLiteral("[abc]?")
|
|
((call_expression
|
|
(navigation_expression
|
|
((simple_identifier) @_class
|
|
(#eq? @_class "Regex"))
|
|
(navigation_suffix
|
|
((simple_identifier) @_function
|
|
(#eq? @_function "fromLiteral"))))
|
|
(call_suffix
|
|
(value_arguments
|
|
(value_argument
|
|
[ (line_string_literal) (multi_line_string_literal) ] @injection.content))))
|
|
(#set! injection.language "regex"))
|