plugins {
    id 'java'
}

group = 'de.com.baseband.bot'
version = '1.0-SNAPSHOT'

repositories {
    mavenCentral()
    maven { url = 'https://git.tudbut.de/api/packages/TudbuT/maven' }
    maven { url = 'https://git.tudbut.de/api/packages/BaseBand/maven' }
}

configurations {
    jarLibs
    reloadQuickly {
        resolutionStrategy.cacheDynamicVersionsFor(30, 'seconds')
        resolutionStrategy.cacheChangingModulesFor(30, 'seconds')
    }
}

dependencies {
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.10.0'
    testImplementation 'org.junit.jupiter:junit-jupiter-params:5.10.0'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.10.0'

    reloadQuickly jarLibs('de.tudbut:tuddylib:+')

    reloadQuickly jarLibs("net.dv8tion:JDA:5.0.0-beta.24")

    implementation configurations.jarLibs
}


jar {
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE

    from {
        configurations.jarLibs.collect {
            it.isDirectory() ? it : zipTree(it)
        }
    } {
        exclude "LICENSE.txt", "META-INF/MANIFSET.MF", "META-INF/maven/**", "META-INF/*.RSA", "META-INF/*.SF"
    }

    manifest.attributes(
            'Main-Class': 'de.com.baseband.bot.Main',
    )

    archiveFileName = "BaseBand-Discord.jar"
}

test {
    useJUnitPlatform()
}